如何把用户选择的记录导出
[讨论] 如何把用户选择的记录导出一般而言，都是通过复制然后打开EXCEL粘贴即可。但是这个方法要打开其他对象如EXCEL等才能实现，而且操作比较麻烦，有一定局限性，如果直接使用DOCMD.OutputTo则不能把用户选择的记录进行输出，而只能对整个表等进行输出。为此提出这个讨论具有必要行。
我的想法是，既然DOCMD.OutputTo只能输出表，所以就可以把选择的记录保存到临时表中再导出就可以解决问题。但是再使用中我遇到了问题，希望高手们一起来讨论这个问题
With Me.subMC.Form '子表单subMC
Dim intStartR As Integer '定义用户选择的开始记录号
Dim intEndR As Integer '定义用户选择的结束记录号
Dim intRows As Integer '定义用户选择的行数
'Dim i As Integer
'Dim strSQL As String
If .SelHeight > 0 Then
intStartR = .CurrentRecord
intEndR = .SelTop + .SelHeight
intRows = intEndR - intStartR '获取用户选择的记录,注意的是用户必须从上而下选择记录,而不能从下而上选择记录
'strSQL = "Select * INTO tmpTemp FROM whMC2 Where MCNo='" & .MCNo & "' AND Item='" & .Item & "'"
'If intEndR - intStartR >= 1 Then
' For i = (intStartR + 1) To intEndR
' strSql1 = "再把其他记录追加到表"
' Next i
'End If
Dim rst As ADODB.Recordset '定义当前记录集
Set rst = .RecordsetClone
Dim intFieldCount As Integer '定义并获取当前记录集的字段数量
intFieldCount = rst.Fields.Count
Dim arrGetR As Variant, x As Integer, y As Integer '定义记录集数组,上标和下标
arrGetR = rst.GetRows(intRows, .Bookmark) '获取记录集的指定行数
'=================================================================循环输出记录
For x = 0 To intRows - 1 '
For y = 0 To intFieldCount - 1
Debug.Print arrGetR(y, x) & ";";
Next y
Debug.Print vbCrLf
Next x
'=================================================================循环输出记录
End If
'DoCmd.RunSQL strSQL
'DoCmd.OutputTo acOutputTable, "tmpTemp", , , True
End With
问题就在于这里，如何把循环输出的记录写如一个带字段名称的表中？以前在一个台湾人写的access书写的一个财务管理方面的书中有介绍，可是现在忘记怎么操作了，希望高手指点 最新回复
tmtony at 2008-3-11 21:14:59
刚才还没有测试出来,继续试, 这么快就发上来了
hunrybecky at 2008-3-11 21:28:39
是呀，一个下午和晚上都在搞这个。
hunrybecky at 2008-3-11 21:33:03
写到这里，已经可以正确判断用户选择的记录了。但是如何写到表中并导出呢？
andymark at 2008-3-11 21:33:13
用 DoCmd.TransferSpreadsheet 可以导出表可查询的
andymark at 2008-3-11 21:37:06
我通过查询来导出的, 因为导出的格式基本一样,所以主要设置好查询的字段就基本满足查询的数据的要求
Dim StrExcelName As String
Dim StrFilename As String
StrFilename = Me.TxtCcode & "总表.xls"
StrExcelName = CurrentProject.Path & "\ExcelFile\" & StrFilename
If Dir(StrExcelName) <> "" Then
Kill StrExcelName
End If
DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel8, "汇总报表", StrExcelName, True
andymark at 2008-3-11 21:39:41
汇总报表 为查询名
tmtony at 2008-3-11 22:04:26
他主要想法,是想用户随选随导, 没有固定的条件
andymark at 2008-3-11 22:25:06
能否做个简单的例子上来测试
t小宝 at 2008-3-11 22:31:48
用下面这种方式添加数据到电子表格，在不安装EXCEL的电脑上也行，而且速度快
Dim dbs As New ADODB.Connection
Dim rst As New ADODB.Recordset
Dim sName As String
sName = "c:\人员表.xls"
' 建立电子表格 （用一个空的数据源新建一个电子表格，这样表格只有字段名一行）
CurrentDb.Execute "Select * INTO [Excel 8.0;DATABASE=" & sName & "].Sheet1 FROM (Select * From 人员表 Where false)"
' 连接电子表格
dbs.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & sName & ";Extended Properties=""Excel 8.0;"""
' 以记录集方式打开电子表格
rst.Open "Select * from [Sheet1$]", dbs, adOpenForwardOnly, adLockOptimistic
' 然后在这里把数组中的数据循环添加到表格记录集中
rst.AddNew
rst!("姓名") = "张三"
rst.Update
tmtony at 2008-3-11 23:03:12
看看, 他的原目的未达到, 倒引出了不少精彩代码
t小宝 at 2008-3-11 23:19:13
把10楼的代码改一点加到1楼的这段代码中应该可以实现吧，把 Debug.Print 改为 Add，不过我还没试过
'=================================================================循环输出记录
For x = 0 To intRows - 1 '
For y = 0 To intFieldCount - 1
Debug.Print arrGetR(y, x) & ";";
Next y
Debug.Print vbCrLf
Next x
'=================================================================循环输出记录
andymark at 2008-3-11 23:21:50
如果要输出字段名称, X须从1开始
t小宝 at 2008-3-11 23:55:29
下面代码我测试过了，可行。在子窗体中选择记录，在主窗体的一个标签上单击。
Private Sub Label2_Click()
With Me.Xzc.Form '子表单subMC
If .SelHeight > 0 Then
Dim intStartR As Integer '定义用户选择的开始记录号
Dim intEndR As Integer '定义用户选择的结束记录号
Dim intRows As Integer '定义用户选择的行数
Dim dbs As New adodb.Connection
Dim rst1 As New adodb.Recordset ' 电子表格记录集
Dim rst As dao.Recordset '定义当前记录集
Dim arrGetR As Variant, x As Integer, y As Integer '定义记录集数组,上标和下标
Dim intFieldCount As Integer '定义并获取当前记录集的字段数量
Dim sName As String, st1 As String
Set rst = .RecordsetClone
intFieldCount = rst.Fields.Count
intStartR = .CurrentRecord
intEndR = .SelTop + .SelHeight
intRows = intEndR - intStartR '获取用户选择的记录,注意的是用户必须从上而下选择记录,而不能从下而上选择记录
arrGetR = rst.GetRows(intRows) ', .Bookmark) '获取记录集的指定行数
sName = "c:\tmpOpt.xls" ' 表格路径名称
' 获取子窗体数据源 如果数据源是SQL语句，后面有分号，改了一下，去掉分号
st1 = Trim(.RecordSource)
If Right(st1, 1) = ";" Then st1 = Left(st1, Len(st1) - 1)
st1 = "(Select * From (" & st1 & ") Where False)"
' 建立并打开电子表格
CurrentDb.Execute "Select * INTO [Excel 8.0;DATABASE=" & sName & "].Sheet1 FROM " & st1
dbs.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & sName & ";Extended Properties=""Excel 8.0;"""
rst1.Open "Select * from [Sheet1$]", dbs, adOpenForwardOnly, adLockOptimistic
'=================================================================循环输出记录
For x = 0 To intRows - 1
rst1.AddNew
For y = 0 To intFieldCount - 1
rst1.Fields(y) = arrGetR(y, x)
Next y
rst1.Update
Next x
'=================================================================循环输出记录
End If
End With
End Sub
[ 本帖最后由 t小宝 于 2008-3-12 00:12 编辑 ]
tmtony at 2008-3-12 01:48:26
有启发!!
hunrybecky at 2008-3-12 14:19:37
我现在思路转换了下。在表中增加了一个选种字段，这样用户可以进行任意选择，不再受连续选择的限制了，而且比较灵活，所以我想这个上比较好的方法，而且不再需要写如表。
hunrybecky at 2008-3-12 19:32:36
本来想用ADOX把获取的SQL生成一个查询，可是老是出现错误，调试了很久，真找不出自己哪里错了。代码如下，注意环境是ADP
Function TT(strQName As String)
Dim cat As New ADOX.Catalog
Set cat.ActiveConnection = CurrentProject.Connection
Dim cmd As New ADODB.Command
cmd.CommandText = "Select * FROM whMC2"
cat.Views.Append strQName, cmd
End Function
0.jpg
hunrybecky at 2008-3-12 19:33:55
最好把表和代码弄到MDB中，测试通过。天拿，这ADP还真难搞。
真想把ADP换成MDB算了，一直用的DAO全部转想ADO太麻烦了。
tmtony at 2008-3-12 19:35:04
小不点, 出错时,代码停在哪一行?
hunrybecky at 2008-3-13 08:37:35
王大哥，如你所说，我真的很灰心了。决定把ADP换回MDB，反正，MDB也支持连接表到SQL。
hunrybecky at 2008-3-13 09:42:27
转MDB也发现问题不少，主要是老是掉线，出现ODBC调用失败，有时刷新连接表可以解决问题，有时非要把数据库关闭重新打开。
(责任编辑：admin)
