'作 者: 朱亦文
Public Const DB_Text As Long = 10
Public Const DB_Boolean As Long = 1
Public Function AddAppProperty(strName As String, varType As Variant, varvalue As Variant) As Integer
Dim dbs As Object, prp As Variant
Const conPropNotFoundError = 3270
Set dbs = CurrentDb
On Error GoTo AddProp_Err
dbs.Properties(strName) = varvalue
AddAppProperty = True
AddProp_Bye:
Exit Function
AddProp_Err:
If Err = conPropNotFoundError Then
Set prp = dbs.CreateProperty(strName, varType, varvalue)
dbs.Properties.Append prp
Resume
Else
AddAppProperty = False
Resume AddProp_Bye
End If
End Function
Public Function ChangeMyAccessTitle(strTitle As String) As Integer
' 设置ACCESS主窗体的标题
ChangeMyAccessTitle = AddAppProperty("AppTitle", DB_Text, strTitle)
Application.RefreshTitleBar ' 刷新标题栏，设置ACCESS的标题
End Function
Public Function ChangeMyAccessIco(strIcoPath As String) As Integer
' 设置ACCESS主窗体的图标
ChangeMyAccessIco = AddAppProperty("AppIcon", DB_Text, strIcoPath)
Application.RefreshTitleBar ' 刷新标题栏，设置ACCESS的图标
End Function
'如果想要把 ACCESS 的图标改在 C:\my.ico, 则只要这样就可以了：
'iX = ChangeMyAccessIco("C:\my.ico")
'如果想要更改ACCESS的图标和数据库在同一个文件夹里, 则只要这样就可以了：
'iX = ChangeMyAccessIco("CurrentProject.Path & "\MSN.ico")
'如果想要把 ACCESS 的标题改为"我的应用程序"，则只要这样：
'iX = ChangeMyAccessTitle("我的应用程序")