Office中国论坛/Access中国论坛

标题: 【Access小品】入乡随俗 -- 中位数函数示例 [打印本页]

作者: todaynew 时间: 2015-7-24 17:23
标题: 【Access小品】入乡随俗 -- 中位数函数示例
　　版友羽竹w同志问如何分组查询求某字段的中位数。在分组查询中可以用到的统计函数有限，没有现成的求中位数的函数。如果直接编写查询语句会比较麻烦，所以解决此类问题，宜采用自定义函数的方法。

　　除了SQL中有域函数外，VBa也存在域函数。所谓“域”，也就是字段，所以域函数是针对字段的函数，一般用于二维表的纵向计算。VBa中的域函数具有显著的特征，其一是函数名以大写的D开头，其二是形参依次为字段名、表名、条件。

　　求某字段的中位数的函数，实际上就是一种域函数。所以编写这类自定义函数时，我们可以入乡随俗，按照系统域函数的特点进行编写。这样处理的好处是，可以使其他程序人员快速的理解和使用。

　　什么是中位数呢？所谓中位数就是一组数据排序后处于中间位置的那个数。当这组数据的个数是奇数时，这不难处理。当个数为偶数时，则需要取中间两数的平均值。明白了这个概念，编写一个自定义函数就不困难了。我们可以写成如下：

Public Function DMedian(ByVal fieldname As String, ByVal tbname As String, ByVal wh As String) As Double
'功能：返回中位数
'参数：fieldname -- 求中位数的字段名称
'    tbname -- 表或查询名称
'    wh -- 筛选条件
Dim rs As New ADODB.Recordset
Dim ssql As String
Dim i As Long
Dim cnt As Long
Dim d As Double

ssql = "select " & fieldname & " from " & tbname & " where " & wh & " order by " & fieldname
rs.Open ssql, CurrentProject.Connection, adOpenKeyset, adLockOptimistic
cnt = rs.RecordCount
If cnt Mod 2 = 0 Then
      '记录条数为偶数取中间两个数字的平均数
      i = Int(cnt / 2)
      rs.Move i - 1
      d = rs.Fields(fieldname).Value
      rs.MoveNext
      d = d + rs.Fields(fieldname).Value
      d = d / 2
Else
      '记录条数为奇数取中间数字
      i = Int(cnt / 2) + 1
      rs.Move i - 1
      d = rs.Fields(fieldname).Value
End If
rs.Close: Set rs = Nothing
DMedian = d
End Function

示例：[attach]56936[/attach]

视图：
[attach]56937[/attach]

作者: cpxie 时间: 2015-7-24 20:06
学习了

作者: 风中漫步 时间: 2015-7-25 08:25
什么是中位数呢？所谓中位数就是一组数据排序后处于中间位置的那个数。

作者: 风中漫步 时间: 2015-7-25 08:26
谢谢分享

作者: woshinide 时间: 2016-8-14 17:31
outlook有没有录制宏之类的功能呢

作者: owen2016 时间: 2016-8-20 11:05
已经下载学习

欢迎光临 Office中国论坛/Access中国论坛 (http://www.office-cn.net/)