ADO作为窗体数据源，一段可读写，一段只读，为什么？

老鬼

两段用ADO连接SQL SERVER并作为窗体数据源，一段可读写，一段只读，为什么？

1. Private Sub Form_Open(Cancel As Integer)
   
2.    '这段在窗体上可读写
   
3.    Dim cn As ADODB.Connection
   
4.    Dim rs As ADODB.Recordset
   
5. 
   
6.    Set cn = New ADODB.Connection
   
7.    With cn
   
8.       .Provider = "Microsoft.Access.OLEDB.10.0"
   
9.       .Properties("Data Provider").Value = "SQLOLEDB"
   
10.       .Properties("Data Source").Value = "127.0.0.1"
    
11.       .Properties("User ID").Value = "sa"
    
12.       .Properties("Password").Value = "密码"
    
13.       .Properties("Initial Catalog").Value = "库名"
    
14.       .Open
    
15.    End With
    
16. 
    
17.    Set rs = New ADODB.Recordset
    
18.    With rs
    
19.       Set .ActiveConnection = cn
    
20.       .Source = "SELECT * FROM TblAssets"
    
21.       .LockType = adLockOptimistic
    
22.       .CursorType = adOpenKeyset
    
23.       .Open
    
24.    End With
    
25.    
    
26.    Set Me.Recordset = rs
    
27.    Set rs = Nothing
    
28.    Set cn = Nothing
    
29. End Sub

复制代码

1. Private Sub Form_Open(Cancel As Integer)
   
2.    '这段在窗体上为只读
   
3.    Dim cn As ADODB.Connection
   
4.    Dim rs As ADODB.Recordset
   
5. 
   
6.    Set cn = New ADODB.Connection
   
7.    cn.Open "Provider=SQLOLEDB;Server=127.0.0.1;Database=库名;UID=sa;PWD=密码;"
   
8. 
   
9.    Set rs = New ADODB.Recordset
   
10.    With rs
    
11.       Set .ActiveConnection = cn
    
12.       .Source = "SELECT * FROM TblAssets"
    
13.       .LockType = adLockOptimistic
    
14.       .CursorType = adOpenKeyset
    
15.       .Open
    
16.    End With
    
17.    
    
18.    Set Me.Recordset = rs
    
19.    Set rs = Nothing
    
20.    Set cn = Nothing
    
21. End Sub

复制代码

老鬼

说明一下：两段代码不一样的地方只有cn的连接字符串。

zhuyiwen

前一段的ADO的提供者是Microsoft.Access.OLEDB.10.0，后一段的提供者是SQLOLEDB，这就是原因。

layaman_999

zhuyiwen 发表于 2012-8-29 21:02
前一段的ADO的提供者是Microsoft.Access.OLEDB.10.0，后一段的提供者是SQLOLEDB，这就是原因。

学习了

老鬼

zhuyiwen 发表于 2012-8-29 21:02
前一段的ADO的提供者是Microsoft.Access.OLEDB.10.0，后一段的提供者是SQLOLEDB，这就是原因。

那后一段怎么改可以读写呢？

老鬼

改成下面这样可以读写了，{:soso_e113:}

1. cn.Open "Provider=Microsoft.Access.OLEDB.10.0;Data Provider=SQLOLEDB;Server=127.0.0.1;Database=库名;UID=sa;PWD=密码;"

复制代码

zhuyiwen

老鬼 发表于 2012-8-30 09:26
改成下面这样可以读写了，

1. cn.Open "Provider=Microsoft.Access.OLEDB.10.0;Data Provider=SQLOLEDB;Server=127.0.0.1;Database=库名;UID=sa;PWD=密码;"

复制代码

OK!