用代码启动MSDE服务器

zhuyiwen

Public Function sStartMSDE(sSvrName As String, sUID As String, sPWD As String) As String
'********************************************************************
'这个子程序将启动 MSDE. 如果服务器已经启动，则通过错误陷阱退出函数
'
'注：该程序不会在任务条上显示SQL Service Manager.
'
'输入:
'   sSvrName    要启动的服务器名
'   sUID        用于启动服务器的用户名
'   sPWD        口令
'
'输出:
'   解释状态
'
'引用:
'   SQLDMO
'********************************************************************

    Dim osvr As SQLDMO.SQLServer

    Set osvr = CreateObject("SQLDMO.SQLServer")
    '创建 SQLDMO Server 对象
        
    On Error GoTo StartError '转向错误陷阱
   
    osvr.LoginTimeout = 60
    '启动服务器
    osvr.start True, sSvrName, sUID, sPWD
   
    '返回结果
    sStartMSDE = "启动了 " & sSvrName

ExitSub:
    Exit Function

StartError:
    If Err.Number = -2147023840 Then
    '这是服务器已经启动而抛出的错误编码
        osvr.Connect sSvrName, sUID, sPWD '连接到服务器
        
        '返回结果
        sStartMSDE = sSvrName & " 已经启动"
        
    Else '未知错误
        '返回结果 出错描述
        sStartMSDE = Err.Description
    End If
   
    Resume ExitSub
   
End Function

大熊

微软的例子真是值得好好研究！

zhuyiwen

这是MSDN中的例子，真是值得多看看！