【新手入门】之五：公共变量与传址过程、传值过程

lynnwang

我们一般会在下面第二个容易掉进陷井！

Sub testFuns()
    Dim lngRet As Long, varLong As Long
    varLong = 1
    fun1 varLong
    Debug.Print varLong

    varLong = 1
    fun1 (varLong)
    Debug.Print varLong

    varLong = 1
    Call fun1(varLong)
    Debug.Print varLong
   
    varLong = 1
    Call fun1((varLong))
    Debug.Print varLong
   
    varLong = 1
    Call fun1(lng:=varLong)
    Debug.Print varLong

    varLong = 1
    Call fun1(lng:=(varLong))
    Debug.Print varLong
End Sub

Function fun1(ByRef lng As Long) As Integer
    lng = 1000
End Function

输出得到：

1000
1
1000
1
1000
1

应该都看出来了吧，答案：
不管[Sub][Function]，如果对参数变量加了括号，即使过程参数是传址，也会将参数作为传值（参数复本传入过程）
如果还不理解，将fun1改为两个参数(其他稍作修改)再运行，你就会彻底明白

Function fun1(ByRef lng As Long,lng2 As Long) As Integer
    lng = 1000
    lng2=2000
End Function

咱家是猫

真的新手肯定早吓跑了.

zhuyiwen

lynnwang 发表于 2012-9-25 00:39
不管[Sub][Function]，如果对参数变量加了括号，即使过程参数是传址，也会将参数作为传值（参数复本传入过程）

为什么？

zhuyiwen

推演：
参数定义
function x(var as integer)  = function x(byref var as integer)

变量和表达式
传递参数时

1. dim k
   
2. dim a as integer
   
3. k = x(a)    ' 传址，即传的变量的地址，函数内部可以影响 a 的值

复制代码

如果抛弃函数的返回值，VBA 要求如此书写

1. x a    ' 同样传址，函数内部可以影响 a 的值

复制代码

(a) = (a + 0) ' 就 a 数值类型而言
因此 (a) 是表达式，它返回的另一个地址空间中的值，而不是 a 变量地址空间中的值

故：

1. k = x((a)) ' 此时传递的不是 a 的地址，而是表达式 (a) 的地址，此时，函数内部影响的是表达式 (a) 地址空间中的，而不是 a 的值

复制代码

如果抛弃函数返回值，VBA 应该这样写

1. x (a)

复制代码

lynnwang

还是老朱，牛叉，见多识广，分析到点了。

（）＝传值＝值的复本

renyucai1963

学习。

yori2007

tmtming

好好学习.

微微森林

系统性学完。

5574916

学习学习，谢谢分享！